
 1000  *--------------------------------
 1010  *  AUTO/MANUAL TOGGLE
 1020  *
 1030  *  BY ROBERT F. O'BRIEN
 1040  *     14, CLONSHAUGH LAWN, DUBLIN 5.
 1050  *--------------------------------
 1060        .OR $3228
 1070        .TF AUTO/MANUAL PATCH
 1080  *--------------------------------
 1090  CH     .EQ $24
 1100  SC.SLOW    .EQ $11D2
 1110  SC.REENTER .EQ $135E
 1120  SC.RETURN  .EQ $13C3
 1130  SC.INSTALL .EQ $152A
 1140  SC.LIST    .EQ $183F
 1150  MON.BELL   .EQ $FF3A
 1160  *--------------------------------
 1170  AUTO.MANUAL.COMMAND
 1180         CMP #$81     CTRL-A?
 1190         BEQ AUTO.TOGGLE
 1200         CMP #$8C     CTRL-L?
 1210         BEQ LIST
 1220         CMP #$93     CTRL-S?
 1230         BEQ SLOW.LIST
 1240  *
 1250  BACK   JSR MON.BELL
 1260         JMP SC.REENTER    BACK TO ASSEMBLER
 1270  *--------------------------------
 1280  AUTO.TOGGLE
 1290         LDA CH
 1300         CMP #1       BEGINNING OF LINE?
 1310         BEQ AUTO.CMD
 1320         CMP #6       AFTER LINE NUMBER?
 1330         BEQ MANUAL.CMD
 1340         BNE BACK
 1350  *--------------------------------
 1360  AUTO.CMD
 1370         LDX #0
 1380  .1     LDA AUTO.TEXT,X   GET CHARACTER
 1390         JSR SC.INSTALL  PROCESS CHAR
 1400         CPX #5
 1410         BCC .1
 1420         JMP SC.REENTER
 1430  AUTO.TEXT  .AS -/AUTO /
 1440  *--------------------------------
 1450  MANUAL.CMD
 1460         LDX #0
 1470         STX CH       GO TO START OF LINE
 1480  .1     LDA MANUAL.TEXT,X
 1490         JSR SC.INSTALL
 1500         CPX #6
 1510         BCC .1
 1520         JMP SC.RETURN
 1530  MANUAL.TEXT .AS -/MANUAL/
 1540  *--------------------------------
 1550  LIST   LDA CH
 1560         CMP #1       BEGINNING OF LINE?
 1570         BNE BACK
 1580         JSR SC.LIST
 1590         JMP SC.RETURN
 1600  *--------------------------------
 1610  SLOW.LIST
 1620         LDA CH
 1630         CMP #1
 1640         BNE BACK
 1650         JSR SC.SLOW  SET SLOW MODE
 1660         JSR SC.LIST
 1670         JMP SC.RETURN

